物理引擎

package com.mop{  
      import Box2D.Collision.Shapes.b2PolygonDef;  
      import Box2D.Collision.b2AABB;  
      import Box2D.Common.Math.b2Vec2;  
      import Box2D.Dynamics.b2Body;  
      import Box2D.Dynamics.b2BodyDef;  
      import Box2D.Dynamics.b2DebugDraw;  
      import Box2D.Dynamics.b2World;  
        
      import flash.display.Sprite;  
      import flash.events.Event;  
    
      public class BoxTest extends Sprite {  
            
          public var worldAABB:b2AABB = new b2AABB();  
          public var gravity:b2Vec2 = new b2Vec2(0,10);  //重力  
          public var doSleep:Boolean = true; //无互交的刚体不参与模拟计算 提高性能  
          public var world:b2World;  
            
          private var pixelsToMeter:Number = 30;//box2d中 1m = 30px  
    
    
          public function BoxTest() {  
              //包围体定义，物理世界模拟的范围  
              worldAABB.lowerBound.Set(-100,-100);  
              worldAABB.upperBound.Set(100,100);  
              //物理世界  
              world = new b2World(worldAABB,gravity,doSleep);  
              //刚体定义  
              var bodyDef:b2BodyDef = new b2BodyDef();  
              bodyDef.position.Set(8,11);//位置定义  
              bodyDef.userData = new PhysGround();  
              var half_groudwidth:Number = 30;//物体的一半宽,单位m  
              var half_grounheight:Number = 3;  
              bodyDef.userData.width =  pixelsToMeter*half_groudwidth*2;  
              bodyDef.userData.height = pixelsToMeter*half_grounheight*2;  
              addChild(bodyDef.userData);  
              //物理形定义  
              var boxDef:b2PolygonDef = new b2PolygonDef();  
              boxDef.SetAsBox(half_groudwidth,half_grounheight);  
              boxDef.density = 0; //密度为0,可漂浮  
              boxDef.friction = 0.3; //摩擦力  
              //根据刚体定义创建刚体实体  
              var body:b2Body = world.CreateBody(bodyDef);  
              //根据物理形定义设置刚体  
              body.CreateShape(boxDef);  
              //依据形计算质量  
              body.SetMassFromShapes();  
                
              //调试模式绘制  
              var dbgDraw:b2DebugDraw = new b2DebugDraw();  
              var dbgSprite:Sprite = new Sprite();  
              addChild(dbgSprite);  
              dbgDraw.m_sprite = dbgSprite;  
              dbgDraw.m_drawScale = 30.0;  
              dbgDraw.m_fillAlpha = 0.0;  
              dbgDraw.m_lineThickness = 1.0;  
              dbgDraw.m_drawFlags = 0xFFFFFFFF;  
              world.SetDebugDraw(dbgDraw);  
                
              //同理添加物体  
              for (var index:int = 0; index < 10; index++) {  
                  bodyDef = new b2BodyDef();  
                  bodyDef.position.x = Math.random() * 15 + 5;  
                  bodyDef.position.y = Math.random() * 10;  
                  var hW:Number = Math.random() + 0.5;  
                  var hH:Number = Math.random() + 0.5;  
    
                  boxDef = new b2PolygonDef();  
                  boxDef.SetAsBox(hW, hH);  
                  boxDef.density = 1.0;  
                  boxDef.friction = 0.5;  
                  boxDef.restitution = 0.2; //弹力  
                  bodyDef.userData = new PhysBox();  
                  bodyDef.userData.width = hW * 2 * pixelsToMeter;  
                  bodyDef.userData.height = hH * 2 * pixelsToMeter;  
                  body = world.CreateBody(bodyDef);  
                  body.CreateShape(boxDef);  
                    
                  body.SetMassFromShapes();  
                  addChild(bodyDef.userData);  
              }  
              addEventListener(Event.ENTER_FRAME, Update, false, 0, true);  
          }  
            
          public function Update(e:Event):void{  
              world.Step(1/30, 10);  
              for (var bb:b2Body = world.m_bodyList; bb; bb = bb.m_next){  
                  if (bb.m_userData is Sprite){  
                      bb.m_userData.x = bb.GetPosition().x * 30;  
                      bb.m_userData.y = bb.GetPosition().y * 30;  
                      bb.m_userData.rotation = bb.GetAngle() * (180/Math.PI);  
                  }  
              }  
          }  
            
            
      }  
}