4.2 PowerBI分析模板-RFM模型

加入 PowerBI自己学 知识星球 可以：下载源文件，边学边练；遇到问题，提问交流，有问必答。

RFM是一种客户价值模型，常见于CRM（客户关系管理）中，按照R（Recency，购买时间间隔）、F（Frequency，购买频率）、M（Monetary，购买金额）3个指标对客户进行分类，基于分类匹配不同的市场营销策略，比如推荐产品、分配拜访、促销等资源。每个指标可以有不同数量的分档，细分为不同数量的分类，本文以每个指标高低两档为例，分类如下：

解决方案

在PowerBI中，可以实现随时间推移的动态RFM模型，快速反映市场变化。计算R、F、M的值，与设定好的参数做对比，生成R、F、M的高低分类，然后再生成RFM分类。

举例

基于如下模型进行RFM分析，展示不同分类的客户数，以及每种分类下的客户明细。

销售表

度量值

Recency = DATEDIFF(MAX(Fact_Sales[日期]),MAX(Dim_Date[Date]),DAY)

Frequency = DISTINCTCOUNT(Fact_Sales[日期])

Sales = SUM('Fact_Sales'[金额])

#Customer = COUNTROWS('Dim_Customer')

#Customer_Acitve = CALCULATE([#Customer], FILTER(VALUES(Dim_Customer[客户]), [Sales]>0))

操作步骤

STEP 1 点击菜单栏建模下的新建参数，选择数值范围，新建3个参数，用于区隔R、F、M的高低。以Recency区隔为例。

STEP 2 书写R、F、M和RFM分类度量值。

Segment_R = IF([Sales]>0, IF([Recency]<=[Recency区隔 值],1,0))

Segment_F = IF([Sales]>0, IF([Frequency]>=[Frequency区隔 值],1,0))

Segment_M = IF([Sales]>0, IF([Sales]>=[Monetary区隔 值],1,0))

Segment_RFM =

IF([Sales]>0,

SWITCH(TRUE(),

[Segment_R]=1 && [Segment_F]=1 && [Segment_M]=1, "重要价值客户",

[Segment_R]=1 && [Segment_F]=0 && [Segment_M]=1, "重要深耕客户",

[Segment_R]=0 && [Segment_F]=1 && [Segment_M]=1, "重要唤醒客户",

[Segment_R]=0 && [Segment_F]=0 && [Segment_M]=1, "重要挽留客户",

[Segment_R]=1 && [Segment_F]=1 && [Segment_M]=0, "潜力客户",

[Segment_R]=1 && [Segment_F]=0 && [Segment_M]=0, "新客户",

[Segment_R]=0 && [Segment_F]=1 && [Segment_M]=0, "一般维持客户",

[Segment_R]=0 && [Segment_F]=0 && [Segment_M]=0, "流失客户"

)

)

STEP 3 为了实现RFM分类表与度量值的互动，书写客户数的度量值。

#Customer_PerSegment_RFM =

SUMX(VALUES(Dim_Segment_RFM[Segment]),

CALCULATE(

CALCULATE([#Customer],

FILTER(VALUES(Dim_Customer[客户]),

[Segment_RFM]=SELECTEDVALUE(Dim_Segment_RFM[Segment])

)

)

)

)

STEP 4 为了让表视觉对象可随RFM分类表筛选变化，书写用于筛选的度量值，放入表视觉对象的筛选器，选择等于1。

Filter = IF([Segment_RFM] IN VALUES(Dim_Segment_RFM[Segment]), 1, 0)

STEP 5 在表视觉对象中，为了让明细按照RFM分类的顺序显示，按住Shift键，依次点击Segment_M、Segment_R、Segment_F，按这3列排序。

选择2023年11月、12月和2024年1月，设定3个区隔参数的值，结果如下：

在左侧柱状图中，选中重要唤醒客户，右侧的明细表中对应显示相应的客户，如下：