S7-SCL 统计Dword中,位ON和OFF个数

   VAR_INPUT 
      value : DWord;   // tag where the bit states has to be counted
      numberOfBits : USInt;   // number of bits in input tag "value", in case of Byte=8, Word=16, Dword=32
   END_VAR

   VAR_OUTPUT 
      countBitsFalse : USInt;   // number of bits are false in input tag
      countBitsTrue : USInt;   // number of bits are true in input tag
   END_VAR

   VAR_TEMP 
      tempBinaryValues : DWord;   // temp tag to store and work on the input value
      tempLoopIndex : DInt;   // temp tag for iterating trough tag via loop
      tempCountBitsTrue : USInt;   // temp tag to count bits are true
      tempCountBitsFalse : USInt;   // temp tag to count bits are false
   END_VAR

   VAR CONSTANT 
  //常数.主要方便程序阅读
      ZERO : USInt := 0;   // numeric zero used for initialization
      INCREMENT : USInt := 1;   // numeric one to increment counters
      SHIFT_ON_BIT_RIGHT : USInt := 1;   // numeric one to shift bits one position to the right
      START_INDEX : DInt := 1;   // start index for FOR loop is one, because of the given number of bits 
   END_VAR

  REGION Logic
    // init counter tags 初始化参数
    #tempCountBitsFalse := #ZERO;
    #tempCountBitsTrue := #ZERO;
    #tempBinaryValues := #value;
    
    // iterate over input tag 迭代输入标签
    FOR #tempLoopIndex := #START_INDEX TO USINT_TO_DINT(#numberOfBits) DO
      // check if bit is true or false 检查位为ON还是OFF
      IF #tempBinaryValues.%X0 THEN
        #tempCountBitsTrue += #INCREMENT;
      ELSE
        #tempCountBitsFalse += #INCREMENT;
      END_IF;
      
      // shift input tag one to the right 右移一位
      #tempBinaryValues := SHR(IN := #tempBinaryValues, N := #SHIFT_ON_BIT_RIGHT);
    END_FOR;
    
    // set output values  输出处理
    #countBitsFalse := #tempCountBitsFalse;
    #countBitsTrue := #tempCountBitsTrue;
    
    // no error handling needed
    ENO := TRUE;
  END_REGION