文章/答案/技术大牛

发布

社区首页 >问答首页 >是否有任何方法可以删除具有相同进程名称的条目？

问是否有任何方法可以删除具有相同进程名称的条目？
EN

Stack Overflow用户

提问于 2017-11-09 07:54:44

回答 2查看 84关注 0票数 1

我正在尝试获得内存消耗最大的10个进程，并且我正在使用在这个Question中提供的代码作为答案。它工作得很好，只是我不希望多个进程条目占用不同的内存大小，而且我无法对其进行排序，因为它的内存消耗是不同的。守则是：

@echo off
setlocal EnableDelayedExpansion

(for /F "skip=1 tokens=1,2" %%a in ('wmic process get name^,workingsetsize') do (
set "size=         %%b"
echo !size:~-10!:%%a
)) > wmicc.txt
set i=0
for /F "skip=1 delims=" %%a in ('sort /R wmicc.txt') do (
echo %%a
set /A i+=1
if !i! equ 25 goto :end
)
:end

我能得到的输出如下：

96931840:iexplore.exe
82161664:explorer.exe
42319872:svchost.exe
31469568:dwm.exe
25690112:SearchIndexer.exe
17002496:taskhostex.exe
11007590:VCExpress.exe
8033894:avp.exe
7190528 :Skype.exe
7000416 :SkypeBrowserHost.exe

而不是现有代码的输出：

96931840:iexplore.exe
82161664:explorer.exe
42319872:svchost.exe
33656832:svchost.exe
31469568:dwm.exe
26943488:iexplore.exe
25690112:SearchIndexer.exe
18550784:svchost.exe
17002496:taskhostex.exe
16343040:svchost.exe

windows

batch-file

cmd

wmic

taskmanager

回答 2

Stack Overflow用户

回答已采纳

发布于 2017-11-09 17:37:42

@echo off
setlocal EnableDelayedExpansion

set num=25

set /A skip=-num
for /F "skip=1 tokens=1,2" %%a in ('wmic process get name^,workingsetsize') do (
   set "size=         %%b"
   set "size=!size:~-10!"
   if not defined proc[%%a] (
      set "proc[%%a]=!size!"
      set "size[!size!:%%a]=1"
      set /A skip+=1
   ) else if %%b gtr !proc[%%a]! (
      set "size[!proc[%%a]!:%%a]="
      set "proc[%%a]=!size!"
      set "size[!size!:%%a]=1"
   )
)

if %skip% lss 1 (set "skip=") else set "skip=skip=%skip%"
for /F "%skip% tokens=2 delims=[]" %%a in ('set size[') do echo %%a

输出示例：

   5517312:NisSrv.exe
   5537792:HD-LogRotatorService.exe
   5939200:spoolsv.exe
   6062080:WUDFHost.exe
   6168576:igfxpers.exe
   6279168:conhost.exe
   6369280:wmpnetwk.exe
   6533120:hkcmd.exe
   6692864:igfxtray.exe
   8073216:notepad.exe
   8077312:WMIC.exe
   8105984:taskhost.exe
   9306112:lsass.exe
  11157504:winlogon.exe
  11767808:taskhostex.exe
  13402112:SkyDrive.exe
  16629760:TabTip.exe
  17121280:SearchIndexer.exe
  26120192:HD-Agent.exe
  32325632:csrss.exe
  36429824:svchost.exe
  43114496:dwm.exe
 101998592:explorer.exe
 110260224:MsMpEng.exe
 114425856:chrome.exe

票数 1

Stack Overflow用户

发布于 2017-11-09 09:16:57

@echo off
setlocal EnableDelayedExpansion

for /f "delims==" %%a in ('set @ 2^>nul') do set "%%a="

(for /F "skip=1 tokens=1,2" %%a in ('wmic process get name^,workingsetsize') do (
set "size=         %%b"
echo !size:~-10!:%%a
)) > wmicc.txt
set i=0
for /F "skip=1 delims=" %%a in ('sort /R wmicc.txt') do (
 for /f "tokens=1*" %%p in ("%%a") do (
  rem the following line doesn't work
  rem if not defined "@%%q"
  rem the preceding line doesn't work
  SET "flag="
  FOR /f "tokens=1*delims==" %%v IN ('set @%%q 2^>nul') DO IF /i "%%v"=="@%%q" SET "flag=Y"
  IF NOT DEFINED flag (
   set "@%%q=Y"
   echo %%a
   set /A i+=1
   if !i! equ 25 goto :end
  )
 )
)
:end

这个标记将读取到%%p,q的整行标记，因此%%q包含进程名。然后检查变量@processname是否已定义，如果未定义，则生成报告行并设置@processname，以便在定义该变量时，第一次提及将是最后一次。

第一行被设计为将任何现有的@*变量设置为空；如果不存在@*变量，并且插入符号转义>，告诉cmd >是要执行的命令的一部分，而不是for，则>将取消错误消息。

后来

看来，我发明的if defined "varname"实际上不起作用，尽管在我测试它时，它看起来很有效。我已经用代码代替了这个指令，并把它标记出来了。

票数 0

页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持

原文链接：

https://stackoverflow.com/questions/47196635

复制

相似问题

问是否有任何方法可以删除具有相同进程名称的条目？
EN

回答 2

Stack Overflow用户

Stack Overflow用户

社区

活动

圈层

关于

腾讯云开发者

热门产品

热门推荐

更多推荐

问是否有任何方法可以删除具有相同进程名称的条目？EN

回答 2

Stack Overflow用户

Stack Overflow用户

社区

活动

圈层

关于

腾讯云开发者

热门产品

热门推荐

更多推荐

问是否有任何方法可以删除具有相同进程名称的条目？
EN